GT5-Unofficial/build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'

file "build.properties" withReader {
    def prop = new Properties()
    prop.load(it)
    ext.config = new ConfigSlurper().parse prop
}

version = "${config.gt.version}"
group= "gregtech"
archivesBaseName = "gregtech"

minecraft {
    version = "${config.minecraft.version}-${config.forge.version}"
	mappings = "snapshot_20160518"
    runDir = "run"
}

configurations {
    provided
    embedded
    compile.extendsFrom provided, embedded
}

repositories {
    maven {
        name 'Forge'
        url 'http://files.minecraftforge.net/maven'
    }
    maven {
        name = "chickenbones"
        url = "http://chickenbones.net/maven/"
    }
    maven {
        name = "ic2, forestry"
        url = "http://maven.ic2.player.to/"
    }
    maven { // EnderIO & EnderCore
        name 'tterrag Repo'
        url "http://maven.tterrag.com"
    }
    maven { // AppleCore
        url "http://www.ryanliptak.com/maven/"
    }
    maven { //JEI
        url "http://dvs1.progwml6.com/files/maven/"
    }
    ivy {
        name "BuildCraft"
        artifactPattern "http://www.mod-buildcraft.com/releases/BuildCraft/[revision]/[module]-[revision]-[classifier].[ext]"
    }
    ivy {
        name 'CoFHLib'
        artifactPattern "http://addons-origin.cursecdn.com/files/${config.cofhlib.cf}/[module]-[revision].[ext]"
    }
    ivy {
        name 'CoFHCore'
        artifactPattern "http://addons-origin.cursecdn.com/files/${config.cofhcore.cf}/[module]-[revision].[ext]"
    }
    ivy {
        name 'Railcraft'
        artifactPattern "http://addons-origin.cursecdn.com/files/${config.railcraft.cf}/[module]_[revision].[ext]"
    }
	ivy {
        name 'IC2NuclearControl'
        artifactPattern "http://addons-origin.cursecdn.com/files/${config.nc.cf}/[module]-[revision].[ext]"
    }
}

dependencies {
    //provided ("appeng:appliedenergistics2:${config.ae2.version}:dev") {
    //    exclude module: '*'
    //}
    provided "codechicken:CodeChickenLib:${config.minecraft.version}-${config.codechickenlib.version}:deobf"
	//provided "codechicken:CodeChickenCore:${config.minecraft.version}-${config.codechickencore.version}:dev"
    //provided "codechicken:NotEnoughItems:${config.minecraft.version}-${config.nei.version}:dev"
    provided "net.industrial-craft:industrialcraft-2:${config.ic2.version}:dev"
    deobfCompile "net.sengir.forestry:forestry_${config.minecraft.version}:${config.forestry.version}"
    deobfCompile "mezz.jei:jei_${config.minecraft.version}:+"
    //provided "applecore:AppleCore:${config.applecore.version}:api"
    //provided "com.enderio.core:EnderCore:${config.enderiocore.version}:dev"
    //provided ("com.enderio:EnderIO:${config.enderio.version}:dev") {
    //    transitive = false
    //}
    //provided name: 'buildcraft', version: config.buildcraft.version, classifier: "dev", ext: 'jar'
    //provided name: 'CoFHLib', version: config.cofhlib.version, ext: 'jar'
    //provided name: 'CoFHCore', version: config.cofhcore.version, ext: 'jar'
    //provided name: 'Railcraft', version: config.railcraft.version, ext: 'jar'
    //provided name: 'IC2NuclearControl', version: config.nc.version, ext: 'jar'
}

jar.exclude("**.bat")

compileJava {
    sourceCompatibility = "1.8"
    targetCompatibility = "1.8"
    options.encoding = "UTF-8"
}

processResources
{
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task source(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
    manifest {
        attributes 'FMLCorePlugin': 'gregtech.asm.ASM'
        attributes 'FMLCorePluginContainsFMLMod': 'true'
    }
}

jar {
    manifest {
        attributes 'FMLCorePlugin': 'gregtech.asm.ASM'
        attributes 'FMLCorePluginContainsFMLMod': 'true'
    }
}

task dev(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
    manifest {
        attributes 'FMLCorePlugin': 'gregtech.asm.ASM'
        attributes 'FMLCorePluginContainsFMLMod': 'true'
    }
}

artifacts {
    archives dev
	archives source
}