plugins {
    id 'babric-loom' version '1.5-SNAPSHOT'
    id 'maven-publish'
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

loom {
    gluedMinecraftJar()
    customMinecraftManifest.set("https://babric.github.io/manifest-polyfill/${minecraft_version}.json")
    intermediaryUrl.set("https://maven.glass-launcher.net/babric/babric/intermediary/%1\$s/intermediary-%1\$s-v2.jar")
}

repositories {
    maven {
        name = 'Babric'
        url = 'https://maven.glass-launcher.net/babric'
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "babric:barn:${project.yarn_mappings}:v2"
    modImplementation "babric:fabric-loader:${project.loader_version}"

    implementation 'org.slf4j:slf4j-api:1.8.0-beta4'
    implementation 'org.apache.logging.log4j:log4j-slf4j18-impl:2.16.0'
    implementation 'com.googlecode.json-simple:json-simple:1.1.1'
}

processResources {
    inputs.property "version", project.version

    filesMatching('fabric.mod.json') {
        expand "version": project.version
    }
}

java {
    withSourcesJar()

    sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8
}

jar {
    from('../LICENSE') {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

sourceSets {
    main {
        java {
            srcDirs = [
                '../src/shared',
                '../src/fabric-shared',
                '../src/rpc-simple',
                '../src/babric',
            ]
            include '**/*.java'
        }
        resources {
            srcDirs = ['../src', '../src/babric']
            include 'fabric.mod.json'
            include 'flashii-extensions.mixins.json'
            include 'assets/icon.png'
        }
    }
}